파워포인트 쪽번호 넣기 설정하는 방법

2022. 5. 3. 21:18 / 서기랑

 파워포인트의 쪽번호는 워드와 같이 어렵지 않게 넣을 수 있다.

 하지만 워드와 비교하면 기능이 별로 없어 단순히 번호를 넣는 것 외에 원하는 스타일을 적용하고자 한다면 직접 수정하거나 매크로를 이용해야 한다.

 

파워포인트 쪽번호 설정

1. 기본적인 쪽번호 넣기.

 파워포인트 상단 메뉴에서 [삽입 -> 머리글/바닥글]을 클릭하여 실행.

머리글/바닥글 설정

 머리글/바닥글 설정 창이 나타나면 [슬라이드 번호]를 체크하고 [모두 적용] 버튼을 클릭하자.

 ([적용] 버튼은 현재 페이지만 적용되기 때문에 [모두 적용]을 클릭해야 한다.)

슬라이드 번호 표시 설정

 참고로 [제목 슬라이드에는 표시 안 함]을 체크하면 레이아웃이 [제목 슬라이드]로 되어있는 슬라이드에는 쪽번호가 나타나지 않는다.

 보통 첫 페이지를 ppt의 제목 슬라이드로 사용하는 경우가 많은 만큼 알아두면 도움이 될 것이다.

 (그냥 슬라이드 번호의 체크를 해제하고 현제 페이지만 적용해도 된다.)

 

2. 두 번째 페이지를 1쪽으로 시작하기.

 쪽번호는 순서대로 번호가 부여되기 때문에 첫 번째 제목 슬라이드의 쪽번호를 표시하지 않아도 두 번째 페이지의 쪽번호는 2번부터 나타나게 된다.

 이것이 싫다면 슬라이드 시작 번호를 0으로 변경하는 약간의 꼼수를 이용하면 된다.

 

 슬라이드 시작 번호는 파워포인트 상단 메뉴에서 [디자인 -> 페이지 설정]을 클릭하여 실행.

페이지 설정

 페이지 설정 창이 나타나면 [슬라이드 시작 번호]를 [0]으로 변경하고 [확인] 버튼을 클릭하자.

슬라이드 시작 번호 설정

3. 원하는 슬라이드부터 1쪽으로 시작하기.

 기본적으로 슬라이드 번호는 쪽번호를 표시하지 않는 페이지도 포함하여 순서대로 부여되기 때문에 원하는 부분부터 쪽번호를 1쪽으로 시작하고자 한다면 구역 나누기와 매크로를 이용하는 것이 좋다.

 

 구역을 나누고자 하는 슬라이드를 선택.

 파워포인트 상단의 [홈 -> 구역 -> 구역 추가]를 클릭하면 구역을 나눌 수 있다.

슬라이드 구역 나누기

 구역을 나눴다면 이제 매크로를 만들고 실행하여 구역별로 쪽번호가 부여되도록 하면 된다.

 키보드의 [Alt + F11]을 눌러 VBA를 실행.

 VBA 창이 나타나면 왼쪽의 프로젝트 창에서 마우스 우클릭으로 메뉴를 열고 [삽입 - 모듈]을 클릭.

vba 모듈 삽입

 모듈 창이 나타나면 아래의 코드를 붙여 넣자.

 (출처 : 파워포인트 구역별 슬라이드 번호를 채번하고 싶은데 가능한가요? https://answers.microsoft.com)

Sub AddPageNumberBySection()
    Dim pres As Presentation
    Dim sld As Slide, shp As Shape
    Dim s&, f&  'long
    Set pres = ActivePresentation
    'pres.Designs(1).SlideMaster.HeadersFooters.SlideNumber.Visible = msoTrue
    'each section
    For s = 1 To pres.SectionProperties.Count
        'each slide in a section
        For f = 1 To pres.SectionProperties.SlidesCount(s)
            Set sld = pres.Slides(pres.SectionProperties.FirstSlide(s) + f - 1)
            Set shp = getPageNo(sld)
            If shp Is Nothing Then
                With getPageNo(sld.CustomLayout)
                    Set shp = sld.Shapes.AddPlaceholder(ppPlaceholderSlideNumber, .Left, .Top, .Width, .Height)
                End With
            End If
            With shp.TextFrame.TextRange
                '.InsertSlideNumber  '기본 페이지번호
                .Text = f & " / " & pres.SectionProperties.SlidesCount(s)  '페이지번호 / 구역 전체 페이지
                '.text = "- " & f & " -"              '구역내 페이지 번호
                '.Font.Name = "Calibri"
                '.Font.Size = 12
                '.Font.Color = RGB(137, 137, 137)
                '.ParagraphFormat.Alignment = ppAlignRight
            End With
        Next f
    Next s
End Sub

Function getPageNo(oSld As Variant) As Shape
    Dim oShp As Shape
    'Debug.Print oSld.Shapes.Placeholders.Count
    For Each oShp In oSld.Shapes
        If oShp.Type = msoPlaceholder Then
            If oShp.PlaceholderFormat.Type = ppPlaceholderSlideNumber Then
                Set getPageNo = oShp
                Exit For
            End If
        End If
    Next oShp
End Function

슬라이드 쪽 번호 매크로 코드

 코드를 붙여넣었다면 VBA 창을 닫고 파워포인트로 돌아와 키보드의 [Alt + F8]을 누르자.

 매크로 창이 나타나면 매크로를 실행하면 된다.

파워포인트 매크로 실행

 해당 매크로를 통해 쪽번호를 넣게 되면 무조건 구역의 처음 부분부터 1쪽이 된다.

 이는 슬라이드 시작 번호의 설정도 무시하고 1번으로 부여되기 때문에 제목 페이지는 제외하고 쪽번호를 부여하고자 한다면 제목 페이지만 단독으로 구역을 나누고 사용하거나 코드에서 파란색으로 표시된 [f] 부분을 [f-1]로 변경하자.

 

 페이지 표시 형태는 구역 현재 페이지 / 구역 전체 페이지로 설정해 뒀지만 전체 페이지가 표시되는 것이 싫다면 코드에서 빨간색 표시된 [& " / " & pres.SectionProperties.SlidesCount(s)]부분을 삭제하면 된다.

 

4. 쪽번호 위치 변경.

 쪽번호의 위치는 기본이 오른쪽 아래에 위치하지만 슬라이드 마스터를 통해 위치를 변경할 수 있다.

 슬라이드 마스터는 상단 메뉴의 [보기 -> 슬라이드 마스터]를 클릭하여 실행.

슬라이드 마스터 실행

 쪽 번호의 위치를 변경하고자 하는 레이아웃을 선택한 뒤 오른쪽 하단에 <#>이 표시되어있는 상자의 위치를 변경하면 된다.

슬라이드 쪽번호 위치 변경

 

그 외 내용

- 위 방법 외에도 여러가지 꼼수도 존재한다.

 인쇄시 페이지 번호가 문제라면 페이지 번호가 필요 없는 제목 페이지들은 전부 ppt 마지막 페이지로 이동하고 쪽번호가 보이지 않게 인쇄하거나 프레젠테이션을 위한 것이라면 파일을 나누고 링크를 이용하는 방법 등이 있다고 한다.

 

- 쪽번호는 직접 변경이 가능하니 페이지가 얼마 없다면 그냥 변경하는 것이 편하다.

 (한번 수정하면 해당 페이지는 그 뒤부터 자동으로 변경되지 않는다.)